* Test problem 9.3.4 in the Test Collection Book
* Test problem 9.2.3 in the web page
* Test problem from Visweswaran etal 1996
* Originally from Shimizu Aiyoshi 81
* Ouadratic Outer and Inner Objective - Nonlinear

*********************************************
* This program locates the LOCAL minimum
*********************************************

SET i /1*6/;

PARAMETER bigu;

bigu = 400;

VARIABLES

y1, y2, z;

POSITIVE VARIABLES

x1, x2, s(i), lb(i);

EQUATIONS

ob, o1, c1, c2, c3, c4, c5, c6, cs(i), kt1, kt2;

* Outer Objective function

ob.. 2*x1 + 2*x2 - 3*y1 - 3*y2 - 60 =e= z;

* Outer Problem Constraints

o1..   x1 + x2 + y1 - 2*y2  =l= 40;

* Inner Problem Constraints

c1.. - x1 + 2*y1 + s('1') =e= -10;

c2.. - x2 + 2*y2 + s('2') =e= -10;

c3..      -   y1 + s('3') =e= 10;

c4..          y1 + s('4') =e= 20;

c5..      -   y2 + s('5') =e= 10;

c6..          y2 + s('6') =e= 20;


* KKT conditions for the inner problem optimum

kt1.. 2*(y1 - x1 + 20) + 2*lb('1') - lb('3') + lb('4') =e= 0;
kt2.. 2*(y2 - x2 + 20) + 2*lb('2') - lb('5') + lb('6') =e= 0;


* Complementarity Constraints

cs(i).. s(i)*lb(i) =e= 0;

x1.l = 1;
x1.l = 1;
y1.l = -8;
y2.l = -8;

x1.up = 50;
x2.up = 50;
s.up(i)  = 200;
lb.up(i) = 200;

MODEL VISHY/ALL/;

SOLVE VISHY USING NLP MINIMIZING z;