* Test problem 9.2.8 in the Test Collection Book
* Test problem 9.1.7 in the web page
* Test Problem from Bard and Falk 1982
* Originally from Candler-Townsley 78

SET i /1*6/;

PARAMETER bigu;

bigu = 10;

VARIABLES

z;

POSITIVE VARIABLES

x1, x2, y1, y2, y3, s(i), lb(i);

BINARY VARIABLES

yb(i);

EQUATIONS

c1, c2, c3, c4, c5, c6, c7, kt1, kt2, kt3, cs1(i), cs2(i);

* Outer Objective function

c1.. -8*x1 - 4*x2 + 4*y1 - 40*y2 + 4*y3 =e= z;

* Inner Problem Constraints

c2.. -y1 + y2 + y3 + s('1') =e= 1;

c3.. 2*x1 - y1 + 2*y2 - 0.5*y3 + s('2') =e= 1;

c4.. 2*x2 + 2*y1 - y2 - 0.5*y3 + s('3') =e= 1;

c5.. - y1 + s('4') =e= 0;

c6.. - y2 + s('5') =e= 0; 

c7.. - y3 + s('6') =e= 0;

* KKT conditions for the inner problem optimum

kt1..  -lb('1') - lb('2') + 2*lb('3') - lb('4') =e= -1;

kt2..   lb('1') + 2*lb('2') - lb('3') - lb('5') =e= -1;

kt3..   lb('1') - 0.5*lb('2') - 0.5*lb('3') - lb('6') =e= -2;

* Complementarity Constraints

cs1(i).. lb(i) - bigu*yb(i) =l= 0;
cs2(i)..  s(i) - bigu*(1 - yb(i)) =l= 0;


MODEL BARDFALK/ALL/;

SOLVE BARDFALK USING MIP MINIMIZING z;