*--------------------------------------------------------------*
* Test Problem 3 from Chapter 8, section 5.5                   *
* Nonlinear Model                                              *
*--------------------------------------------------------------*

Sets
    m  number of data sets      /1*25/
    n  number of variables      /1*2/
    p  number of parameters     /1*2/;
 
Parameters 
   ze(m,n)   observed data values
   std(n)    standard deviations;

Variables 
   z(m,n)    fitted data variables
   a(p)      model parameters
   c         cost function;
   
table ze(m,n)
       1        2
1    0.113    1.851
2    0.126    1.854
3    0.172    1.849
4    0.155    1.815
5    0.219    1.828
6    0.245    1.847
7    0.274    1.804
8    0.264    1.832
9    0.312    1.838
10   0.324    1.817
11   0.333    1.820
12   0.399    1.845
13   0.417    1.829
14   0.419    1.832
15   0.439    1.820
16   0.475    1.820
17   0.506    1.799
18   0.538    1.838
19   0.538    1.835
20   0.591    1.811
21   0.578    1.794
22   0.626    1.825 
23   0.659    1.801
24   0.668    1.810
25   0.687    1.802;

std(n) = 1;

Equations
      obj         objective function
      con(m)      non-convex equality constraint;

obj.. c =e= sum(m,sum(n,sqr((z(m,n)-ze(m,n))/std(n))));

con(m) .. -z(m,'2') + a('1') + 1/(z(m,'1') - a('2')) =e= 0;
    
model
     problem /obj,con/;

z.lo(m,n) = ze(m,n) - 0.5;
z.up(m,n) = ze(m,n) + 0.5;

a.lo('1') = 1;
a.lo('2') = 2;

a.up('1') = 10;
a.up('2') = 10;

z.l(m,n) = uniform(z.lo(m,n),z.up(m,n));
a.l(p) = uniform(a.lo(p), a.up(p));

solve problem using nlp minimizing c;