#*************************************************************
# Test Problem 6 from Chapter 11, section 3.7  
# Lotka-Volterra Problem: 2 Parameter Predator-Prey Model
#*************************************************************

OPTION {{
  FTOL = 1e-6;
  OTOL = 1e-6;
  NLP = "SNOPT";
  RANDOMX;
}}

DECLARATION {{
  INDEX {m,i,p};
  SET M = |1:10|;  # Number of Data sets
  SET I = |1:2|;   # Number of Variables
  SET P = |1:2|;   # Number of Parameters


  XVAR {x(M,I), # Fitted data variables
        a(P)    # Parameters
       };

  ZVAR {z(I)};
  ISPE {z(I)};
  ZINC {1.2,1.1};
  TIME {0,1,2,3,4,5,6,7,8,9,10};

# Observed data 
  PARA xe(M,I) = {0.7990, 1.0758,
                  0.8731, 0.8711,
                  1.2487, 0.9393,
                  1.0362, 1.1468,
                  0.7483, 1.0027,
                  1.0024, 0.8577,
                  1.2816, 1.0274,
                  0.8944, 1.1369,
                  0.7852, 0.9325,
                  1.1527, 0.9074};

# Variable Bounds
  LBDS x(M,I) = < m E M | < i E I | 0.5 > >;
  UBDS x(M,I) = < m E M | < i E I | 1.5 > >;

  LBDS a(P) = < p E P | 0>; 
  UBDS a(P) = < p E P | 10>;

  
}}

MODEL {{
  MIN:  <<m E M | <<i E I | (xe(m,i) - x(m,i))^2 >> >>;

  dae1: z'(1) =e= a(1)*z(1)*(1 - z(2));
  dae2: z'(2) =e= a(2)*z(2)*(z(1) - 1);

  err(m E M,i E I)[m]:  z(i) - x(m,i) =e= 0;

}}