* System of nonlinear equations
* Circuit design problem (Ratschek and Rokne, 1993).
* 1 known solution

* Sets
SET i /1*9/;
SET j /1*5/;
SET k /1*4/;

* Parameters
PARAMETER g(j,k)  
         / '1'.'1'     0.485
           '1'.'2'     0.752
           '1'.'3'     0.869
           '1'.'4'     0.982
           '2'.'1'     0.369
           '2'.'2'     1.254
           '2'.'3'     0.703
           '2'.'4'     1.455
           '3'.'1'     5.2095
           '3'.'2'     10.0677
           '3'.'3'     22.9274
           '3'.'4'     20.2153
           '4'.'1'     23.3037
           '4'.'2'     101.779
           '4'.'3'     111.461
           '4'.'4'     191.267
           '5'.'1'     28.5132
           '5'.'2'     111.8467
           '5'.'3'     134.3884
           '5'.'4'     211.4823/;

VARIABLES
	 x(i)  
	 s  
     objval    objective function variable;

FREE VARIABLES    objval;


EQUATIONS
	 f Objective function
	 h1p(k)  
	 h1m(k)  
	 h2p(k)  
	 h2m(k)  
	 h3 ; 

f  .. objval =e=s;
h1p(k)  .. g('4',k)*x('2') - s + (1 - x('1')*x('2'))*x('3')*(EXP(x('5')*(g('1',k) - g('3',k)*0.001*x('7') - g('5',k)*0.001*x('8'))) - 1) =l= g('5',k);
h1m(k)  .. -g('4',k)*x('2') - s  -(1 - x('1')*x('2'))*x('3')*(EXP(x('5')*(g('1',k) - g('3',k)*0.001*x('7') - g('5',k)*0.001*x('8'))) - 1) =l= -g('5',k);
h2p(k)  .. -g('5',k)*x('1') - s + (1 - x('1')*x('2'))*x('4')*(EXP(x('6')*(g('1',k) - g('2',k) - g('3',k)*0.001*x('7') + g('4',k)*0.001*x('9'))) - 1) =l= -g('4',k);
h2m(k)  .. g('5',k)*x('1') - s -(1 - x('1')*x('2'))*x('4')*(EXP(x('6')*(g('1',k) - g('2',k) - g('3',k)*0.001*x('7') + g('4',k)*0.001*x('9'))) - 1) =l= g('4',k);
h3  .. x('1')*x('3') - x('2')*x('4') =e= 0;

* Bounds
x.LO(i)  = 0;
x.UP(i)  = 10;

* Starting point
* x.L('1') = 0.89999;
* x.L('2') = 0.44999;
* x.L('3') = 1.00001;
* x.L('4') = 2.00007;
* x.L('5') = 7.99997;
* x.L('6') = 7.99969;
* x.L('7') = 5.00003;
* x.L('8') = 0.99999;
* x.L('9') = 2.00005;

MODEL test /ALL/;
SOLVE test USING NLP MINIMIZING objval;