* Test problem 10.2.7 in the web page
* Section 10.3.8 in test problem collection
* Test problem from MCPLIB

SET J Process /1*10/;
SET I Capital Good /1*2/;
SET K Resources /1*2/;

TABLE A(I,J) Capital Input Matrix
   1   2   3   4   5   6   7   8   9    10
1  2   2   2   2   2   2   2   2   2    2
2  3   3   2   2   1   1   1   0.5 1  0.5;


TABLE B(I,J) Capital Output Matrix
   1   2   3   4   5   6   7   8   9    10
1  1.5 1.5 1.5 1.5 1.5 1.5 4   3  1.5  1.5
2  2.7 2.7 1.8 1.8 0.9 0.9 0.9 0.4 2   1.5;


TABLE C(K,J) Resource Input Matrix
   1   2   3   4   5   6   7   8   9    10
1  1   1   1   1   1   1   1   1   1    1
2  0.5 1.5 1.5 0.5 0.5 1.5 1.5 0.5 0.5  1.5;

PARAMETER alpha Discount Factor;
alpha = 0.7;

PARAMETER w(K) Constant on the Resources Available/
1 0.8
2 0.8/;

PARAMETER p;
p = 0.2;


POSITIVE VARIABLES x(J),y(I),u(K);
EQUATIONS f(J), f7(I), f8(K);

f(J).. - ( p*(  x('1') + 2.5*x('2') )**(p-1) *((2.5*x('3') 
               + x('4') )**p)*((  2*x('5') 
               + 3*x('6') )**p))$(ord(J) eq 1)

     - ( p*2.5*((  x('1') + 2.5*x('2'))**(p-1))*((2.5*x('3')  
               + x('4') )**p)*((2*x('5') 
               + 3*x('6'))**p))$(ord(J) eq 2)

     - ( p*2.5*((  x('1')+2.5*x('2'))**p)*((2.5*x('3')
               + x('4'))**(p-1))*((2*x('5') 
               + 3*x('6'))**p))$(ord(J) eq 3)

     - ( p*((  x('1') +2.5*x('2'))**p)*((2.5*x('3')
               + x('4'))**(p-1))*((2*x('5') 
               + 3*x('6'))**p))$(ord(J) eq 4)

     - ( p*2*((  x('1') +2.5*x('2'))**p)*((2.5*x('3')
               + x('4'))**p)*((2*x('5') 
               + 3*x('6'))**(p-1)))$(ord(J) eq 5)

     - ( p*3*((  x('1') +2.5*x('2'))**p)*((2.5*x('3')
               + x('4'))**p)*((2*x('5') 
               + 3*x('6'))**(p-1)))$(ord(J) eq 6) 

               + sum(I, ( A(I,J) - alpha*B(I,J) )*y(I))
	       + sum(K, C(K,J)*u(K)) =g= 0;

f7(I)..  sum(J, (B(I,J) - A(I,J))*x(J)) =g= 0;
f8(K).. -sum(J, C(K,J)*x(J)) + w(K) =g= 0;

MODEL HANKO /f.x, f7.y, f8.u/;

*Option limrow = 0;
*option limcol = 0;
*Option iterlim = 2000;
*Option reslim = 120;
*Option domlim = 100;

x.lo(J) = 2.0e-05;

SOLVE HANKO using mcp;

x.lo(J) = 0;

SOLVE HANKO using mcp