$*************************************************************
$ Financial Optimization: Risk Management 
$
$ H. Dahl, A. Meeraus and S Zenios, "Some Financial 
$   Optimization Models: Risk Management", in S.  Zeios (ed.)
$   "Financial Optimization", Cambridge University Press,
$   New York, NY, 1993
$
$ Alternate formulation
$
$ Optimal Solution:  14.5596
$*************************************************************

DECLARATION {{
  INDEX {i,j};
  SET I = {|1:7|}; #set of securities
  SET J = {|1:7|};

#Expected returns
  PARA mu(I) = {0.1287,0.1096,0.0501,0.1524,0.0763,0.1854,0.0620 };

#Variance
  PARA q(I,J) = {42.18, 40.36, 21.76, 10.60, 24.64, 47.68, 34.82,
                 0.00, 70.89, 43.16, 30.82, 46.48, 47.60, 25.24,
                 0.00,  0.00, 25.51, 19.20, 45.26, 26.44,  9.40,
                 0.00,  0.00,  0.00, 22.30, 20.64, 20.92,  2.00,
                 0.00,  0.00,  0.00,  0.00, 30.01, 32.72, 19.80,
                 0.00,  0.00,  0.00,  0.00,  0.00, 42.23,  0.00,
                 0.00,  0.00,  0.00,  0.00,  0.00,  0.00, 16.42};

#Various data
  PARA old(I) = {0.20, 0.15, 0.00, 0.00, 0.10, 0.15, 0.20};
  PARA umi(I) = {0.03, 0.04, 0.04, 0.03, 0.03, 0.03, 0.03};
  PARA uma(I) = {0.11, 0.10, 0.07, 0.11, 0.20, 0.10, 0.10};
  PARA lmi(I) = {0.02, 0.02, 0.04, 0.04, 0.04, 0.04, 0.04};
  PARA lma(I) = {0.30, 0.15, 0.10, 0.10, 0.10, 0.15, 0.30};

#Variables
  XVAR {x(I), xi(I), xd(I), mv(I)};
  YVAR {y(I), z(I)};
  BINA {y(I), z(I)};

#Bounds
  POSI  {x(I), xi(I), xd(I), mv(I)};
  UBDS x(I)  = <i E I| 1.0>;
  UBDS xi(I) = <i E I| 1.0>;
  UBDS xd(I) = <i E I| 1.0>;
}}

MODEL {{
  MIN:   <<i E I| x(i)*mv(i) >>;
  lbudg: <<i E I| x(i) >> =e= 1;
  lxdef(i E I): x(i) + xd(i) - xi(i) =e= old(i);
  lmxic(i E I): xi(i) - uma(i)*y(i) =l= 0;
  lmiic(i E I): xi(i) - umi(i)*y(i) =g= 0;
  lmxdc(i E I): xd(i) - lma(i)*z(i) =l= 0;
  lmidc(i E I): xd(i) - lmi(i)*z(i) =g= 0;
  lbism(i E I): y(i) + z(i) =l= 1;
  lturn: <<i E I| xi(i) >> =l= 0.3;
  lmvdf(i E I): mv(i) - <<j E J| q(i,j)*x(j) >>  =e= 0;
}}