$*************************************************************
$ Optimal Separation Scheme to be used to separate a
$   multicomponent process stream into a set of product
$   streams with given purity specification
$
$ G.R. Kocis and I.E. Grossmann, "A Modelling and
$   Decomposition Strategy for the MINLP Optimization of
$   Process Flowsheets", Comput. Chem. Eng., 1989, 13 (7),
$   797--819.
$
$ Optimal Solution:  510.081
$*************************************************************

DECLARATION {{
  XVAR {p1a, p1b, p2a, p2b,
        f1, f2, f3a, f3b, f4a, f4b, f5a, f5b, f6a, f6b,
        f7a, f7b, f8a, f8b, f9a, f9b, f10a, f10b, f11a, f11b};
  XVAR {e4, e5, e6};
  YVAR {yd, yf};
  BINA {yd, yf};
  XLBD {0,0,0,0,
        0,0,0,0,0,0,0,0,0,0,
        0,0,0,0,0,0,0,0,0,0,
        0,0,0};
  XSTP {10};
  XUBD {50,50,50,50,
        25,25,50,50,50,50,50,50,50,50,
        50,50,50,50,50,50,50,50,50,50,
        1,1,1};
  YSTP {1,0};
}}

MODEL {{
  MIN: -35*p1a - 30*p2b + 10*f1 + 8*f2 + f4a + f4b + 4*f5a
       + 4*f5b + 2*yf + 50*yd;
  mixer11: f3a =e= 0.55*f1 + 0.50*f2;
  mixer12: f3b =e= 0.45*f1 + 0.50*f2;
  splitter1: f4a =e= e4*f3a;
  splitter2: f4b =e= e4*f3b;
  splitter3: f5a =e= e5*f3a;
  splitter4: f5b =e= e5*f3b;
  splitter5: f6a =e= e6*f3a;
  splitter6: f6b =e= e6*f3b;
  splitter7: f7a =e= f3a - f4a - f5a - f6a;
  splitter8: f7b =e= f3b - f4b - f5b - f6b;
  flash1: f8a =e= 0.85*f4a;
  flash2: f8b =e= 0.20*f4b;
  flash3: f9a =e= 0.15*f4a;
  flash4: f9b =e= 0.80*f4b;
  distil1: f10a =e= 0.975*f5a;
  distil2: f10b =e= 0.050*f5b;
  distil3: f11a =e= 0.025*f5a;
  distil4: f11b =e= 0.950*f5b;
  mixer21: p1a =e= f8a + f10a + f6a;
  mixer22: p1b =e= f8b + f10b + f6b;
  mixer31: p2a =e= f9a + f11a + f7a;
  mixer32: p2b =e= f9b + f11b + f7b;
  logical1: f4a + f4b =g= 2.5*yf;
  logical2: f4a + f4b =l= 25*yf;
  logical3: f5a + f5b =g= 2.5*yd;
  logical4: f5a + f5b =l= 25*yd;
  spec1: p1a =g= 4*p1b;
  spec2: p2b =g= 3*p2a;
  spec3: p1a + p1b =l= 15;
  spec4: p2a + p2b =l= 18;
#  logical5: e4 + e5 + e6 =l= 1;
#  logical6: 33*e4 - 2.5*yf =g= 0;
#  logical7: 33*e5 - 2.5*yd =g= 0;
#  logical8: yf + yd =g= 1;
}}