$*************************************************************
$ Optimal Design of Multiproduct Batch Plants
$
$ G.R. Kocis and I.E. Grossmann, "Global Optimization of
$   Nonconvex Mixed-Integer Nonlinear Programming (MINLP)
$   Problems in Process Synthesis", Ind. Eng. Chem. Res.,
$   1988, 27 (8), 1407--1421.
$
$ Optimal solution:  285,507
$*************************************************************

OPTION {{
  MINOS = "Iterations Limit 100000";
  MINOS = "Major Iterations Limit 1000";
}}

DECLARATION {{
  INDEX {i,j,k,l};
  SET I = |1:5|;
  SET J = |1:6|;
  SET K = |1:4|;
  SET L = |1:2|;
  XVAR {n(J),v(J),a(I),b(I)};
  YVAR {y(K,J)};
  BINARY {y(K,J)};
  PARAM q(I) = {250000.0, 150000.0, 180000.0, 160000.0, 120000.0};
  PARAM t(I,J) = {6.4, 4.7, 8.3,  3.9, 2.1, 1.2,
                  6.8, 6.4, 6.5,  4.4, 2.3, 3.2,
                  1.0, 6.3, 5.4, 11.9, 5.7, 6.2,
                  3.2, 3.0, 3.5,  3.3, 2.8, 3.4,
                  2.1, 2.5, 4.2,  3.6, 3.7, 2.2};
  PARAM s(I,J) = {7.9, 2.0, 5.2, 4.9, 6.1, 4.2,
                  0.7, 0.8, 0.9, 3.4, 2.1, 2.5,
                  0.7, 2.6, 1.6, 3.6, 3.2, 2.9,
                  4.7, 2.3, 1.6, 2.7, 1.2, 2.5,
                  1.2, 3.6, 2.4, 4.5, 1.6, 2.1};
  PARAM lns(I,J) = <i E I| <j E J| log[s(i,j)]>>;
  PARAM lnt(I,J) = <i E I| <j E J| log[t(i,j)]>>;
  PARAM lnk(K) = <k E K| log[k]>;
  PARAM lln(J) = <j E J| 0>;
  PARAM uln(J) = <j E J| log[4]>;
  PARAM llv(J) = <j E J| log[300]>;
  PARAM ulv(J) = <j E J| log[3000]>;
  PARAM lla(I) = <i E I| log[max[j E J| t(i,j)]/4.0]>;
  PARAM ula(I) = <i E I| log[max[j E J| t(i,j)]]>;
  PARAM llb(I) = <i E I| log[(q(i)*max[j E J| t(i,j)])/(6000*4.0)]>;
  PARAM ulb(I) = <i E I| log[q(i) ? min[j E J| 3000/s(i,j)]]>;
  SHOW {lnk(K)};
  SHOW {lla(I)};
  SHOW {ula(I)};
  SHOW {llb(I)};
  SHOW {ulb(I)};
  XUBD {uln(J),ulv(J),ula(I),ulb(I)};
  XLBD {lln(J),llv(J),lla(I),llb(I)};
  YSTP {0,0,0,0,1,0,
        0,1,0,1,0,1,
        1,0,1,0,0,0,
        0,0,0,0,0,0};
#  YSTP {1,1,0,1,1,1,
#        0,0,0,0,0,0,
#        0,0,0,0,0,0,
#        0,0,1,0,0,0};
}}

MODEL {{
  MIN: 250*<<j E J| exp[n(j)+0.6*v(j)]>>;
  ldvj(i E I, j E J): v(j) - b(i) =g= lns(i,j);
  ldct(i E I, j E J): n(j) + a(i) =g= lnt(i,j);
  nhc: <<i E I| q(i)*exp[a(i)-b(i)]>> =l= 6000;
  ldnp(j E J): <<k E K| lnk(k)*y(k,j)>> - n(j) =e= 0;
  ldsy(j E J): <<k E K| y(k,j)>> =e= 1;
}}