$*************************************************************
$ Optimal Design of Multiproduct Batch Plants
$
$ G.R. Kocis and I.E. Grossmann, "Global Optimization of
$   Nonconvex Mixed-Integer Nonlinear Programming (MINLP)
$   Problems in Process Synthesis", Ind. Eng. Chem. Res.,
$   1988, 27 (8), 1407--1421.
$
$ Optimal solution:  285,507
$*************************************************************

OPTION {{
  SNOPT = "Major Iterations Limit 10000";
  SNOPT = "Iterations Limit 100000";
  MINOS = "Iterations Limit 100000";
}}

DECLARATION {{
  INDEX { i, j };
  SET I = |0:4|;
  SET J = |0:5|;

  XVAR { v(J), b(I), tl(I) };
  YVAR { n(J) };
  INTEGER  { n(J) };
  YUBD { 4, 4, 4, 4, 4, 4 };
  YLBD { 1, 1, 1, 1, 1, 1 };

  PARA s(I,J) = { 7.9, 2.0, 5.2, 4.9, 6.1, 4.2,
                  0.7, 0.8, 0.9, 3.4, 2.1, 2.5,
                  0.7, 2.6, 1.6, 3.6, 3.2, 2.9,
                  4.7, 2.3, 1.6, 2.7, 1.2, 2.5,
                  1.2, 3.6, 2.4, 4.5, 1.6, 2.1 };
  PARA t(I,J) = { 6.4, 4.7, 8.3, 3.9, 2.1, 1.2,
                  6.8, 6.4, 6.5, 4.4, 2.3, 3.2,
                  1.0, 6.3, 5.4, 11.9, 5.7, 6.2,
                  3.2, 3.0, 3.5, 3.3, 2.8, 3.4,
                  2.1, 2.5, 4.2, 3.6, 3.7, 2.2 };
  PARAM q(I) = { 250000, 150000, 180000, 160000, 120000 };
  PARAM bil(I) = <i E I| (q(i)*max[j E J| t(i,j) ])/(6000*4.0) >;
  PARAM biu(I) = <i E I| q(i) ? min[j E J| 3000/s(i,j) ] >;
  PARAM til(I) = <i E I| max[j E J| t(i,j) ]/4.0 >;
  PARAM tiu(I) = <i E I| max[j E J| t(i,j) ] >;
  SHOW {tiu(I), til(I)};
  SHOW {biu(I), bil(I)};
       
  UBDS v(J) = { 3000, 3000, 3000, 3000, 3000, 3000 };
  LBDS v(J) = { 300, 300, 300, 300, 300, 300 };
  UBDS b(I) = {biu(I)}; UBDS tl(I) = {tiu(I)};
  LBDS b(I) = {bil(I)}; LBDS tl(I) = {til(I)};

  YSTP {3,3,4,4,3,3};
  XSTP { 3000, 3000, 3000, 3000, 3000, 3000,
         0, 0, 0, 0, 0,
         0, 0, 0, 0, 0};
}}

CONSTRAINTS {{
  MIN: <<j E J| 250*n(j)*v(j)^0.6 >>;
  l1(i E I, j E J): v(j) =g= s(i,j)*b(i);
  l2(i E I, j E J): n(j)*tl(i) =g= t(i,j);
  n3: <<i E I| q(i)*tl(i)/b(i) >> =l= 6000;
}}