$*************************************************************
$ Multi-commodity capacity facility location-allocation
$
$ Optimal Solution:  1.60913e+08
$*************************************************************

DECLARATION {{
  INDEX {i,j,k,p};
  SET I = |1,2|;
  SET J = |1,2|;
  SET K = |1,2|;
  SET P = |1,2|;

  PARAM c(I,J,K,P) = {10,15,20,10,5,5,30,10,25,20,15,20,30,10,10,30};
  PARAM s(I,P) = {100,200,150,120};
  PARAM d(K,P) = {120,140,130,180};
  PARAM f(J) = {2000,2500};
  PARAM v(J) = {50,70};
  PARAM vu(J) = {2500,3200};
  PARAM vl(J) = {50,50};

  XVAR {x(I,J,K,P)};
  YVAR {y(J,K),z(J)};
  BINARY {y(J,K),z(J)};
  POSITIVE {x(I,J,K,P)};
  UBDS x(I,J,K,P) = <i E I| <j E J| <k E K| <p E P| 300> > > >;
  YSTP {1,0,0,1,1,1};
}}

MODEL {{
  MIN: <<i E I| <<j E J| <<k E K| <<p E P| c(i,j,k,p)*x(i,j,k,p) >> >> >> >>
       + <<j E J| f(j)*z(j) >>
       + <<j E J| v(j)*<<i E I| <<k E K| <<p E P| x(i,j,k,p) >> >> >>^2.5>>;
  lsum1(i E I, p E P): <<j E J| <<k E K| x(i,j,k,p) >> >> =l= s(i,p);
  lsum2(j E J, k E K, p E P): <<i E I| x(i,j,k,p) >> =E= d(k,p)*y(j,k);
  lsum3(j E J): <<k E K| <<p E P| d(k,p)*y(j,k) >> >> =l= vu(j)*z(j);
  lsum4(j E J): <<k E K| <<p E P| d(k,p)*y(j,k) >> >> =g= vl(j)*z(j);
  lsum5(k E K): <<j E J| y(j,k)>> =e= 1;
}}