$*************************************************************
$ Problem of Simultaneously determining the optimal structural
$   and operating prameters for a process:  Configuration #3
$
$ M.A. Duran and I.E. Grossmann, "An outer-approximation
$   algorithm for a class of mixed-integer nonlinear programs"
$   Math. Prog. 1986, 36, 307--339
$
$ Example 3
$
$ Optimal Solution:  68.0097
$*************************************************************

DECLARATION {{
  XVAR {x3,x5,x10,x17,x19,x21,x9,x14,x25};
  YVAR {y1,y2,y3,y4,y5,y6,y7,y8};
  XUBD {2,2,1,2,2,2,2,1,3};
  XSTP {1,1,1,1,1,1,1,1,1};
  XLBD {0,0,0,0,0,0,0,0,0};
  BINA {y1,y2,y3,y4,y5,y6,y7,y8};
}}

MODEL {{
  MIN: 5*y1 + 8*y2 + 6*y3 + 10*y4 + 6*y5 + 7*y6 + 4*y7 + 5*y8 -
      10*x3 - 15*x5 + 15*x10 + 80*x17 + 25*x19 + 35*x21 -
      40*x9 + 15*x14 - 35*x25 + exp[x3] + exp[x5/1.2] -
      65*log[x10+x17+1] - 90*log[x19+1] - 80*log[x21+1] + 120;
  n1: -1.5*log[x19+1] - log[x21+1] - x14 =l= 0;
  n2: -log[x10+x17+1] =l= 0;
  l3: -x3 - x5 + x10 +2*x17 + 0.8*x19 + 0.8*x21 - 0.5*x9 -
      x14 - 2*x25 =l= 0;
  l4: -x3 - x5 + 2*x17 + 0.8*x19 + 0.8*x21 - 2*x9 - x14 - 
      2*x25 =l= 0;
  l5: -2*x17 - 0.8*x19 - 0.8*x21 + 2*x9 + x14 + 2*x25 =l= 0;
  l6: -0.8*x19 - 0.8*x21 + x14 =l= 0;
  l7: -x17 + x9 + x25 =l= 0;
  l8: -0.4*x19 - 0.4*x21 + 1.5*x14 =l= 0;
  l9: 0.16*x19 + 0.16*x21 - 1.2*x14 =l= 0;
  l10: x10 - 0.8*x17 =l= 0;
  l11: -x10 + 0.4*x17 =l= 0;
  n12: exp[x3]- 10*y1 =l= 1;
  n13: exp[x5/1.2] - 10*y2 =l= 1;
  l14: x9 - 10*y3 =l= 0;
  l15: 0.8*x19 + 0.8*x21 - 10*y4 =l= 0;
  l16: 2*x17 - 2*x19 - 2*x25 - 10*y5 =l= 0;
  l17: x19 - 10*y6 =l= 0;
  l18: x21 - 10*y7 =l= 0;
  l19: x10 + x17 - 10*y8 =l= 0;
  ld20: y1 + y2 =e= 1; ld21: y4 + y5 =l= 1;
  ld22: -y4 + y6 + y7 =e= 0;
  ld23: y3 - y8 =l= 0;    
}}