$*************************************************************
$ Production Planning in Multipurpose Batch Plants
$ Iftekhar A. Karimi
$
$ CACHE Process Design Case Studies
$ M. Morari and I.E. Grossmann
$
$ Optimal Solution:  -454.249
$*************************************************************

DECLARATION {{
  INDEX {p,r,rr,c};

  SET P = |1:12|; # Products
  SET R = |1:3|;  # Routes
  SET C = |1:20|; # Campaigns

  PARA np = {3};   # Number of products to be produced
  PARA h  = {700}; # Total available plant operation time [h]
  PARA nc = {9};   # Total number of possible campaigns

#Number of routes for products
  PARA nrp(P) = {2, 2, 3, 0, 0, 0, 0, 0, 0, 0, 0, 0};

#Profits of products [$/kg]
  PARA profit(P) = {1.0, 0.8, 0.5, 0, 0, 0, 0, 0, 0, 0, 0, 0};

#Batch sizes of routes [Mg]
  PARA b(P,R) = {2.5 , 2.0 , 0,
                 1.67, 1.33, 0,
                 0.5 , 1.0 , 1.5};

#Times requires to produce one batch for routes [h]
  PARA ct(P,R) = {6.2, 5.4, 1e-10,
                  4.8, 4.0, 1e-10,
                  3.2, 4.9, 6.4};

#Incidence matrix for product routes in campaigns
  PARA rc(P,R,C) = {0};
  PARA rc(1,1,1) = 1;  PARA rc(1,2,1) = 1;  PARA rc(3,1,1) = 1;
  PARA rc(1,1,2) = 1;  PARA rc(2,2,2) = 1;  PARA rc(3,1,2) = 1;
  PARA rc(1,1,3) = 1;  PARA rc(3,1,3) = 1;  PARA rc(3,2,3) = 1;
  PARA rc(1,2,4) = 1;  PARA rc(2,1,4) = 1;  PARA rc(3,1,4) = 1;
  PARA rc(1,2,5) = 1;  PARA rc(3,1,5) = 1;  PARA rc(3,3,5) = 1;
  PARA rc(2,1,6) = 1;  PARA rc(2,2,6) = 1;  PARA rc(3,1,6) = 1;
  PARA rc(2,1,7) = 1;  PARA rc(3,1,7) = 1;  PARA rc(3,2,7) = 1;
  PARA rc(2,2,8) = 1;  PARA rc(3,1,8) = 1;  PARA rc(3,3,8) = 1;
  PARA rc(3,1,9) = 1;  PARA rc(3,2,9) = 1;  PARA rc(3,3,9) = 1;

#Productivity of product routes [Mg/h]
  PARA prtvt(P,R) = <p E P & (p<=np)| <r E R & (r<=nrp(r)) | b(p,r)/ct(p,r) > >;

  XVAR {t(P,R), # Total production times assigned to routes [h]
        q(P),   # Total amounts of products produced [Mg]
        cl(C)   # Lengths of Campaigns [h]
       };

  POSI  {t(P,R), q(P), cl(C)};

  LBDS q(1) = 100; LBDS q(2) = 250; LBDS q(3) = 150;
  UBDS q(1) = 150; UBDS q(2) = 300; UBDS q(3) = 200;
}}

MODEL {{
  MIN:  <<p E P & (p<=np)| -1*profit(p)*q(p) >>;

  production(p E P & (p<=np)): q(p) =e= <<r E R & (r<=nrp(r))| prtvt(p,r)*t(p,r) >>;
  sumcl:  <<c E C & (c<=nc)| cl(c) >> =l= h;
  hconst(p E P & (p<=np), r E R & (r<=nrp(p))): <<c E C & (c<=nc)| rc(p,r,c)*cl(c) >> =g= t(p,r);
}}