$*************************************************************
$ Power Generation via Fuel Oil
$ I. A. Karimi
$
$ CACHE Process Design Case Studies
$ M. Morari and I.E. Grossmann
$
$ Optimal Solution:  4.68089
$*************************************************************

DECLARATION {{
  INDEX {g,f,k};

  SET G = |1:2|; #Power Generators
  SET F = |1:2|; #Fuels
  SET K = |0:2|; #Constants in Fuel Consumption Equations

#Coefficients in the fuel consumption equations
  PARA a(G,F,K) = {1.4609, 0.15186, 0.001450,
                   1.5742, 0.16310, 0.001358,
                   0.8008, 0.20310, 0.000916,
                   0.7266, 0.22560, 0.000778};

#Total power output required [MW]
  PARA preq = 50.0;

  XVAR {p(G),   #Total power output of the generators [MW]
        x(G,F), #Power output of the generators from specific fuels
        z(F)    #Total amount of fuel purchased
       };

  POSI {p(G), x(G,F), z(F)};

  LBDS p(G) = {18.0, 14.0};
  STP  p(G) = {20.0, 20.0};
  UBDS p(G) = {30.0, 25.0};

  UBDS z(2) = {10.0};
}}

MODEL {{
  MIN: z(1);

#Power Requirement
  power1:  <<g E G| p(g) >> =g= preq;

#Power generated
  power2(g E G): p(g) =e= <<f E F| x(g,f) >>;

#Fuel usage
  fuel(f E F): z(f) =g= <<g E G| <<k E K| a(g,f,k)*x(g,f)^k >> >>;

}}