$*************************************************************
$ Design of a Chemical Complex
$ Nikolaos V. Sahinidis and Ignacio E. Grossmann
$
$ CACHE Process Design Case Studies
$ M. Morari and I.E. Grossmann
$
$ Optimal Solution:  -459.35
$*************************************************************

DECLARATION {{
  XVAR {PA,   #purchases of A [tons/hr]
        PB,   #purchases of B [tons/hr]
        SC,   #sales of C [tons/hr]
        BI,   #production rate of B in process I [tons/hr]
        BII,  #consumption rate of B in process II [tons/hr]
        BIII, #consumption rate of B in process III [tons/hr]
        CII,  #production rate of B in process II [tons/hr]
        CIII  #production rate of B in process III [tons/hr]
       };
  XVAR {YI,   #whether or not process I is selected
        YII,  #whether or not process I is selected
        YIII  #whether or not process I is selected
       };
  BINA {YI, YII, YIII};
  POSI {PA, PB, SC, BI, BII, BIII, CII, CIII};
  UBDS SC = {10};
}}

MODEL {{
  MIN:  1000*YI   + 250*PA
      + 1500*YII  + 400*BII 
      + 2000*YIII + 550*BIII
      +  500*PA + 950*PB
      - 1800*SC;

#mass balance for chemicals B and C
  Bmassbal:  BI + PB - BII - BIII =e= 0;
  Cmassbal:  CII + CIII - SC =e= 0;

#balances around processes I, II, and III
  Ibal:      BI =e= 0.9*PA;
  IIbal:    CII =e= 0.82*BII;
  IIIbal:  CIII =e= 0.95*BIII;

#logical constraints
  log1:    PA =l= 16*YI;
  log2:   BII =l= (10/0.82)*YII;
  log3:  BIII =l= (10/0.95)*YIII;

  log4:  YII + YIII =l= 1;
}}