$*************************************************************
$  Chemical Equilibrium
$  I. A. Karimi
$
$ CACHE Process Design Case Studies
$ M. Morari and I.E. Grossmann
$
$  Optimal Solution:  -43.4945
$*************************************************************

DECLARATION {{
  INDEX {i,s};

  SET I = |1:3|;  #Atomic elements
  SET S = |1:10|; #Chemical species

#Pressure of the system
  PARA P = {750};

#Moles of atoms of elements I per mole of Species S
  PARA a(I,S) = {1, 2, 2, 0, 0, 1, 0, 0, 0, 1,
                 0, 0, 0, 1, 2, 1, 1, 0, 0, 0,
                 0, 0, 1, 0, 0, 0, 1, 1, 2, 1};

#Constants in the Chemical Potential Equations
  PARA w(S) = {-10.021, -21.096, -37.986,  -9.846, -28.653,
               -18.918, -28.032, -14.640, -30.594, -26.111};

#Total moles of atoms of elements in the system
  PARA x0(I) = {2,1,1};

  XVAR {x(S), #Moles of component in the system
        f     #total moles in the system
       };

  LBDS x(S) = <s E S| 0.00001>;
  STP  x(S) = {0,1,0,1,0,1,0,1,0,0};
  UBDS x(S) = <s E S| 1.0>;
}}

MODEL {{
  MIN: <<s E S| x(s)*(w(s) + log[P*x(s)/f]) >>;

  total:  f =e= <<s E S| x(s) >>;

  massbal(i E I):  x0(i) =e= <<s E S| a(i,s)*x(s) >>;

}}