$*************************************************************
$ Catalyst Mixing for Packed Bed Reactor
$ L. T. Biegler and I. B. Tjoa
$
$ CACHE Process Design Case Studies
$ M. Morari and I.E. Grossmann
$
$ Optimal Solution:  -0.0163705
$*************************************************************

OPTION {{
  EVTOL = "1e-10";
  FTOL = "1e-6";
  OTOL = "1e-5";
}}

DECLARATION {{
  INDEX {i};
  SET CP = |0:5|; #Control Points
  SET CI = |0:4|; #control Intervals

  XVAR {k(CP),   #control parameters
        tau(CI), #scaling factor for each interval
        j        #objective value
       };

  LBDS j = {0};
  STP  j = {0};
  UBDS j = {10};

  LBDS tau(CI) = <i E CI| 1e-6 >;
  STP  tau(CI) = <i E CI| 1 >;
  UBDS tau(CI) = <i E CI| 100 >;

  LBDS k(CP) = <i E CP| 0 >;
  STP  k(CP) = <i E CP| 1 >;
  UBDS k(CP) = <i E CP| 1 >;

  ZVAR {za,zb,U};
  ISPE {za,zb};
  ZINC {1,0,0};

  PARA time(CP) = {0,1,2,3,4,5};
  TIME            {0,1,2,3,4,5};
}}

MODEL {{
  MIN:  -j;
  dae1: za' =e= interv[i E CI| tau(i)*U*(10*zb - za)];
  dae2: zb' =e= interv[i E CI| tau(i)*U*(za - 10*zb) - tau(i)*(1-U)*zb];
  dae3: U =e= interv[i E CI| k(i) + (k(i+1)
                       - k(i))*(t-time(i))/(time(i+1)-time(i))];
  obj1[5]: j =e= 1 - za - zb;
  tcon:  <<i E CI| tau(i) >> =e= 0.4;
}}