$*************************************************************
$ Minimum Time to Cover a Fixed Distance
$ L. T. Biegler and I. B. Tjoa
$
$ CACHE Process Design Case Studies
$ M. Morari and I.E. Grossmann
$
$ Optimal Solution:  30.0
$*************************************************************

OPTION {{
  EVTOL = "1e-9";
  FTOL = "1e-4";
  OTOL = "1e-4";
}}

DECLARATION {{
  INDEX {i};
  SET CP = |0:5|; #Control Points
  SET CI = |0:4|; #control Intervals

  XVAR {k(CP),   #control parameters
        tau(CI)  #scaling factor for each interval
       };

  LBDS tau(CI) = <i E CI| 0 >;
  STP  tau(CI) = <i E CI| 1 >;
  UBDS tau(CI) = <i E CI| 100 >;

  LBDS k(CP) = <i E CP| -2 >;
  STP  k(CP) = <i E CP|  1 >;
  UBDS k(CP) = <i E CP|  1 >;

  ZVAR {x1,x2,u};
  ISPE {x1,x2};
  ZINC {0,0,0};

  PARA time(CP) = {0,1,2,3,4,5};
  TIME            {0,1,2,3,4,5};
}}

MODEL {{
  MIN:  <<i E CI| tau(i)>>;
  dae1: x1' =e= interv[i E CI| tau(i)*x2];
  dae2: x2' =e= interv[i E CI| tau(i)*u];
  dae3: u =e= interv[i E CI| k(i) + (k(i+1)
                       - k(i))*(t-time(i))/(time(i+1)-time(i))];
  con5[5]: x1 =e= 300;
  con6[5]: x2 =e= 0;
}}