$*************************************************************
$ Optimal Design of Multiproduct Batch Plants
$ Ignacio E. Grossmann
$
$ CACHE Process Design Case Studies
$ M. Morari and I.E. Grossmann
$
$ Optimal Solution:  167,428
$*************************************************************

DECLARATION {{
  INDEX {i,j,k};

  SET I = |1:2|; #products
  SET J = |1:3|; #stages
  SET K = |1:3|; #potential number of parallel units

  PARA q(I)     = {200000, 150000}; #demand of product i [kg]
  PARA alpha(J) = {250, 500, 340};  #cost coefficient
  PARA beta(J)  = {0.6, 0.6, 0.6};  #cost exponent
  PARA s(I,J)   = {2,3,4,           #size factor of product i in stage j [L/kg]
                   4,6,3};
  PARA t(I,J)   = {8,20,4,          #processinig time of product i in stage j [h]
                   10,12,3};

  XVAR {v(J),  #volume of stage j [L]
        b(I),  #batch size of product i [kg]
        tl(I), #cycle time of product i [h]
        n(J)   #number of unit in parallel stage j
       };

  LBDS v(J) = <j E J|log[250] >;
  UBDS v(J) = <j E J|log[2500] >;

  LBDS b(I) = <i E I|log[(q(i)*max[j E J|t(i,j)])/(3*6000)]>;
  UBDS b(I) = <i E I|log[q(i) ? min[j E J|2500/s(i,j)]]>;

  LBDS tl(I) = <i E I|log[max[j E J|t(i,j)]/3.0]>;
  UBDS tl(I) = <i E I|log[max[j E J|t(i,j)]]>;

  LBDS n(J) = <j E J|0>;
  UBDS n(J) = <j E J|log[3]>;

  YVAR {y(K,J)}; #existence of stage
  BINA {y(K,J)};
}}

MODEL {{
  MIN:  <<j E J| alpha(j)*exp[n(j) + beta(j)*v(j)] >>;

#Volume requirement in stage j
  l1(i E I, j E J): v(j) =g= log[s(i,j)] + b(i);

#Cycle time for each product i
  l2(i E I, j E J): n(j) + tl(i) =g= log[t(i,j)];

#Constraint for production time
  n1:  <<i E I| q(i)*exp[tl(i) - b(i)] >> =l= 6000;

#Relating number of units to 0-1 variables
  l3(j E J):  n(j) =e= <<k E K| log[k]*y(k,j) >>;

#Only one choice for parallel units is feasible
  l4(j E J): <<k E K| y(k,j) >> =e= 1;
}}